dism /capture-image /imagefile:d:\backup\win10p_backup.wim /capturedir:c:\ /name:win10_cqcb 

dism /apply-image /imagefile:d:\backup\win10p_backup.wim /applydir:c:\ /index:1 

@echo off
:run_0
cls
set index=
set method=
set search=
set x=
set a=
set b=
set c=
set d=

echo 如果你知晓镜像文件的存放路径，以及操作系统所在盘符，可以跳过查询步骤。
echo 0，退出
echo y，跳过
echo n，查询
set /p search=请选择（0，y，n）：
if not defined search (goto run_0)
if %search% == 0 (goto end) 
if %search% == y (goto begin)
if %search% == n (goto search)

:search
cls
echo 在系统中找到以下有效盘符：
for %%i in (a: b: c: d: e: f: g: h: i: j: k: l: m: n: o: p: q: r: s: t: u: v: w: x: y: z:) do ((dir %%i 1>nul 2>nul)  && (echo %%i))
echo.
for %%i in (a: b: c: d: e: f: g: h: i: j: k: l: m: n: o: p: q: r: s: t: u: v: w: x: y: z:) do ((dir "%%i\Windows\Media\*.wav" 1>nul 2>nul)  && (echo 其中 %%i 是物理 Windows 所在分区))
echo.
echo 正在全盘搜索 mywim.*.wim 镜像文件，请稍候...
for %%i in (a: b: c: d: e: f: g: h: i: j: k: l: m: n: o: p: q: r: s: t: u: v: w: x: y: z:) do (dir /s /b %%i\*.wim 2>nul | findstr /i "mywim")
echo.
echo 请记住上述信息，以便后续操作。
echo.
goto begin

:begin
echo.
echo 操作菜单：
echo 0，退出。
echo 1，制作镜像。
echo 2，恢复镜像。
set /p x=请选择（0，1，2）：

set method=退出
if not defined x (goto run_0)
if %x% == 0 (goto end) 
if %x% == 1 (goto make_wim)
if %x% == 2 (goto recovery_wim) else (goto run_0)

:make_wim
cls
set method=制作镜像
echo 镜像文件名会自动添加 mywim. 的前缀词。
echo 不满足以下条件就返回菜单：
echo 1，【制作源】、【保存到】不能为空。
echo 2，使用有效的绝对路径。&echo.

set /p a=1/4。制作源：
if not defined a (goto run_0)
if "%a:~-1,1%" == "\" (set a=%a:~0,-1%)
(1>nul 2>&1 dir %a%\) || (goto run_0)
echo.

set /p b=2/4。保存到：
if not defined b (goto run_0)
if "%b:~-1,1%" == "\" (set b=%b:~0,-1%)
(1>nul 2>&1 dir %b%\) || (goto run_0)
echo.

echo 在 %b%\ 里有以下镜像文件。
dir %b%\*.wim /b
echo.

set /p c=3/4。镜像文件名：
if not defined c (set c=mywim.Windows%date:~0,4%%date:~5,2%%date:~8,2%%random%)
if not "%c:~0,6%" == "mywim." (set c=mywim.%c%)
set index=%c%
if not "%c:~-4%" == ".wim" (set c=%c%.wim)
echo.

set /p d=4/4。镜像文件索引名：
if not defined d (set d=%index%)

cls
echo 按3次任意键后，将执行如下操作：&echo.
echo 将 %a%\ 制作镜像文件，保存到 %b%，镜像文件名为%c%，镜像文件索引名为 %d% 。&echo.
echo 如果上述信息错误，请按 Ctrl + C 终止。&pause&pause&pause
dism /capture-image /imagefile:%b%\%c% /capturedir:%a%\ /name:%d%
goto end

:recovery_wim
cls
set method=恢复镜像

echo 不满足以下条件就返回菜单：
echo 1，【镜像文件所在目录】、【选择镜像文件】、【恢复到】不能为空。
echo 2，使用有效的绝对路径。&echo.

set /p a=1/4。镜像文件所在目录：
if not defined a (goto run_0)
if "%a:~-1,1%" == "\" (set a=%a:~0,-1%)
(1>nul 2>&1 dir %a%\) || (goto run_0)
echo.

echo 在 %a%\ 里有以下镜像文件。
dir %a%\*.wim /b
echo.

set /p b=2/4。选择镜像文件：
if not defined b (goto run_0)
if not "%b:~-4%" == ".wim" (set b=%b%.wim)
(1>nul 2>&1 dir %a%\%b%) || (goto run_0)
echo.

set /p c=3/4。恢复到：
if not defined c (goto run_0)
if "%c:~-1,1%" == "\" (set c=%c:~0,-1%)
(1>nul 2>&1 dir %c%\) || (goto run_0)
echo.

set /p d=4/4。镜像文件索引号，通常为“1”：
if not defined d (set d=1)

cls
echo 按3次任意键后，将执行如下操作：&echo.
echo 将镜像文件 %a%\%b% 中的第%d%索引，恢复到 %c%\ 。&echo.
echo 如果上述信息错误，请按 Ctrl + C 终止。如果正确无误，按3次任意键后开始执行。&pause&pause&pause&echo.
format %c% /q /y 1>nul 2>nul
dism /apply-image /imagefile:%a%\%b% /applydir:%c%\ /index:%d%
goto end

:end
cls
echo %method%操作完成。欢迎访问个人主页。
echo http://fangyan.win
set index=
set method=
set search=
set x=
set a=
set b=
set c=
set d=

format h: /q /x /fs:fat 
bcdboot c:\windows /s h: /f uefi /l zh-ch 
假设EFI分区盘符为 h: